; To use: /clonescan (for active channel) and: /clonescan #channel (for the given channel)
 
;==========================================================================================
 
on *:load:{
  if ($ial == $true) {
    var %a = 1, %b
    while ($scon(%a)) {
      .scid $v1
      var %x = 1, %y
      while ($chan(%x)) { %y = $v1 | if ($chan(%y).ial == $false) { who %y } | inc %x }
      inc %a
    }
    .scid -r
  }
  echo $color(whois) -tag [Clonescan] $chr(9679) Loaded..
}
 
on me:*:join:#:{ who # }
 
raw 352:*:{ halt }
raw 315:*:{ halt }
 
;==========================================================================================
 
#clonescan on
 
menu channel {
  -
  $iif($server,Clone Scanner) { clonescan # }
  -
}
 
alias clonescan {
  tokenize 32 $iif($1 ischan,$1,$iif($active ischan,$active))
  if ($1 && $server) { 
    echo $color(info) -tag Clonescan in progress for: $1 $+ ...
    var %x 0 , %s 0 , %c 0
    while ($nick($1,%x)) {
      var %x %x + 1 , %n $v1 , %a $address($v1,2)
      if (!$var($+(%,Match.,%a),1) && $ialchan(%a,$1,0) > 1) { var %s %s + 1 , %c %c + $v1 , % $+ [ Match. $+ [ %a ] ] 1 | echo $color(whois) -tag $+([,%s,]) %a $+($chr(40),$regsubex($mid($str($chr(32),$v1),2),//g,$ialchan(%a, [ $1 ] ,\n).nick),$chr(41)) }
    }
    echo $color(info) -tag [Clones] $chr(9679) $iif(!%s,No clones found on $1 $+ .,Clones Found: %c - Clone Sets Found: %s - $1 is: %c $+ / $+ $nick($1,0) $+($chr(40),$round($calc(%c / $nick($1,0) * 100),2),%,$chr(41)) clones)
  }
}
#clonescan end