menu menubar,channel {
  Ayar
  .Kelime Tamamlama: ktamamla
  -
}
alias ktamamla { if ($dialog(ktamamla)) { dialog -c ktamamla } |  dialog -ma ktamamla ktamamla }
dialog ktamamla {
  title "Kelime Tamamlama"
  size -1 -1 215 134
  option dbu
  edit "", 1, 7 9 50 10, autohs
  text " yazdığında", 2, 58 10 30 8
  button "Sil", 3, 51 117 74 12
  edit "", 4, 89 9 80 10, autohs
  text " olarak yazacak", 5, 169 10 38 8
  button "Ekle", 6, 7 23 201 12, default
  box "Kelime Tamamlama", 7, 3 1 209 38
  list 8, 3 41 209 71, size vsbar
  radio "Açık", 9, 149 118 24 10, group left
  radio "Kapalı", 10, 182 118 27 10
  box "", 11, 143 114 69 15
  button "Tamam", 12, 4 117 28 12, ok
}
on *:dialog:ktamamla:*:*: {
  if ($devent == init) {
    if ($group(#ktamamla) == on) { did -c ktamamla 9 } | else { did -c ktamamla 10 }
    ktamamla.init
  }
  if ($devent == sclick) { 
    if ($did == 6) {
      if (($did(1) && $did(4)) != $null) { 
        if !$read(txt\tamamlama.txt,w,$did(1) $+ $chr(186) $+ *) { .write txt\tamamlama.txt $did(1) $+ $chr(186) $+ $did(4) | ktamamla.init | did -r ktamamla 1,4 }
        else { echo 4 -at [ $did(1) ] Kelime tamamlama listesinde ekli }
      }
      else { echo 4 -at Lütfen 2 kutucuğu doldurun }
    }
    if ($did == 3) {
      if $read(txt\tamamlama.txt,w,$token($did(8).seltext,1,47) $+ $chr(186) $+ *) {
        if ($did(8).seltext != $null) { .write $+(-dl,$readn) txt\tamamlama.txt | ktamamla.init } 
      }
    }
    if ($did(9).state == 1) { .enable #ktamamla }
    if ($did(10).state == 1) { .disable #ktamamla }
  }
}
alias ktamamla.init {
  did -r ktamamla 8
  var %ul 1 
  while %ul <= $lines(txt\tamamlama.txt) {
    did -a ktamamla 8 $replace($read(txt\tamamlama.txt,%ul),$chr(186),$chr(47))
    inc %ul
  }
}
#ktamamla on
on *:input:*:{ 
  if !$regex($1,/^(\.|!|\/|[0-9])/i) || ($ctrlenter) { 
    var %^ = 1, %'
    while %^ <= $0 { 
      %' = %' $iif($read(txt\tamamlama.txt,w,$gettok($1-,%^,32) $+ $chr(186) $+ *),$token($read(txt\tamamlama.txt,$readn),2,186),$gettok($1-,%^,32))
      inc %^
    }
    say %'
    halt
  }
}
#ktamamla end